本頁面由 Cloud Translation API 翻譯而成。

FIDL 文法

修改的 BNF 規則

這是 FIDL 來源檔案的文法。文法會以表示經修改的 BNF 格式。

非終端符號會比對其他符號序列，以。

nonterminal = list , of , symbols ;

部分符號是終端符號，雙引號。

another-nonterminal = THESE , ARE , TERMINALS , AND , SO , IS , "this" ;

修改會以直立線表示。

choice = this | that | the-other ;

選項 (零或一個) 會以括號表示。

optional = ( maybe , these ) , but , definitely , these ;

重複 (零或大於零) 會以括號和星號表示。

zero-or-more = ( list-part )* ;

重複 (一或多個) 會以括號和加號表示。

one-or-more = ( list-part )+ ;

憑證

容錯期間，系統會忽略空白字元和註解，因此不會以下列文法表示。

註解的開頭可以是兩個斜線 (「//」) 或三個斜線 ('///')，或者可在 [Doc] 屬性中顯示。三斜線變化版本和 [Doc] 屬性的運作方式相同。將註解傳播至產生的目標。

fidldoc 工具會處理以 JSON 為基礎的註解用於產生參考的中級代表 (IR) FIDL 檔案的說明文件頁面。

詳情請參閱 FIDL 樣式指南留言。

文法

file 是起始符號。

file = library-header , ( using-list ) , declaration-list ;

library-header = ( attribute-list ) , "library" , compound-identifier , ";" ;

using-list = ( using , ";" )* ;

using = "using" , compound-identifier , ( "as" , IDENTIFIER ) ;

compound-identifier = IDENTIFIER ( "." , IDENTIFIER )* ;

declaration-list = ( declaration , ";" )* ;

declaration = const-declaration | layout-declaration | protocol-declaration
    | type-alias-declaration | resource-declaration | service-declaration ;

const-declaration = ( attribute-list ) , "const" , IDENTIFIER ,
    type-constructor , "=" , constant ;

layout-declaration = ( attribute-list ) , "type" , IDENTIFIER , "=" ,
    inline-layout ; [NOTE 1]

inline-layout = ( attribute-list ) , ( declaration-modifiers )* , layout-kind ,
    ( layout-subtype ) , layout-body ;

declaration-modifiers = "flexible" | "strict" | "resource",
    ( modifier-availability ) ; [NOTE 2]

layout-subtype = ":" , type-constructor ; [NOTE 3]

layout-kind = "struct" | "bits" | "enum" | "union" | "table" ;

layout-body = value-layout | struct-layout | ordinal-layout ;

value-layout = "{" , ( value-layout-member , ";" )+ , "}" ;

value-layout-member = ( attribute-list ) , IDENTIFIER , "=" ,
    constant ; [NOTE 4]

struct-layout =  "{" , ( struct-layout-member , ";" )* , "}" ;

struct-layout-member = ( attribute-list ) , member-field ;

ordinal-layout =  "{" , ( ordinal-layout-member , ";" )* , "}" ; [NOTE 5]

ordinal-layout-member = ( attribute-list ) , ordinal , ":" ,
    member-field ;

protocol-declaration = ( attribute-list ) , ( protocol-modifiers )* ,
    "protocol" , IDENTIFIER , "{" , ( protocol-member , ";" )*  , "}" ;

protocol-modifiers = "closed" | "ajar" | "closed" , ( modifier-availability ) ;

protocol-member = protocol-method | protocol-event | protocol-compose ;

protocol-method = ( attribute-list ) , ( method-modifiers )* , IDENTIFIER ,
    parameter-list , ( "->" , parameter-list ,
    ( "error" type-constructor ) ) ; [NOTE 6]

protocol-event = ( attribute-list ) , ( method-modifiers )* , "->" ,
    IDENTIFIER , parameter-list ;

method-modifiers = "strict" | "flexible" , ( modifier-availability ) ;

parameter-list = "(" , ( type-constructor ) , ")" ; [NOTE 7]

protocol-compose = ( attribute-list ) , "compose" , compound-identifier ;

type-alias-declaration = ( attribute-list ) , "alias" , IDENTIFIER ,  "=" ,
    type-constructor ;

resource-declaration = ( attribute-list ) , "resource_definition" , IDENTIFIER ,
    ":" , "uint32" , "{" , resource-properties ,  "}" ;

resource-properties = "properties" , "{" , ( member-field  , ";" )* , "}" , ";"

service-declaration = ( attribute-list ) , "service" , IDENTIFIER , "{" ,
                      ( service-member , ";" )* , "}" ;

service-member = ( attribute-list ) , member-field ; [NOTE 8]

member-field = IDENTIFIER , type-constructor ;

attribute-list = ( attribute )* ;

attribute = "@" , IDENTIFIER , ( "(" , constant | attribute-args , ")" ) ;

attribute-args = attribute-arg | attribute-arg , "," attribute-args ;

attribute-arg = IDENTIFIER , "=" , constant ;

modifier-availability = "(" , attribute-args , ")" ; [NOTE 9]

type-constructor = layout , ( "<" , layout-parameters , ">" ) ,
    ( ":" type-constraints ) ;

layout = compound-identifier | inline-layout ;

layout-parameters = layout-parameter | layout-parameter , "," ,
    layout-parameters ;

layout-parameter = type-constructor | constant ;

type-constraints = type-constraint | "<" type-constraint-list ">" ;

type-constraint-list = type-constraint | type-constraint , "," ,
    type-constraint-list ;

type-constraint = constant ;

constant = compound-identifier | literal ;

ordinal = NUMERIC-LITERAL ;

literal = STRING-LITERAL | NUMERIC-LITERAL | "true" | "false" ;

`STRING-LITERAL`

STRING-LITERAL 的文法如下：

STRING-LITERAL  = "\"" ( unicode-value )* "\"" ;
unicode-value   = literal-char | escaped-basic | escaped-unicode ;
literal-char    = any unicode character except CR, LF, "\" or "\"" ;
escaped-basic   = "\" ( "\" | "\"" | "n" | "r" | "t"  ) ;
escaped-unicode = "\u{" ( hex-digit ){1,6} "}" ;

注意事項 1

匿名版面配置簡介的屬性可置於下列其中一個位置：地區：

在 type 關鍵字前方，或
作為 inline-layout 的一部分。

無法同時將屬性放在兩個位置的單一版面配置定義中看看是否獲得編譯器許可

注意事項 2

文法允許所有宣告使用 ( declaration-modifiers )*，但編譯器對下列項目的限制如下：

同一個宣告不能重複出現兩次。
flexible 和 strict 修飾符無法一起使用。
只有在 layout-kind 情況下才能使用 flexible 和 strict 修飾符為 bits、enum 或 union。
resource 修飾符只有在 layout-kind 為 struct 時才能使用。 table 或 union。

注意事項 3

文法允許所有宣告使用 ( layout-subtype )，但編譯器設有限制只有在 layout-kind 為 bits 或 enum 時，才能使用此設定。

另外，layout-subtype讓模型擁有更多的type-constructor 但編譯器會將此字串限制為帶正負號或無正負號的整數類型 (請參閱基本) 瞭解位元的列舉和無正負號整數類型。

注意事項 4

value-layout-member 允許文法中較為寬鬆的 constant，但編譯器會限制 constant 可能採用的值：

在 enum 中符合指定 subtype 的任何值。
任何符合指定 subtype，且為二次方的次方， bits 上的內容。

注意事項 5

ordinal-layout 文法允許任意數量的成員，但嚴格的聯集明確來說，至少要有一個成員

注意事項 6

protocol-method 錯誤能在更多限制範圍內使用 type-constructor 但編譯器會將此要求限制在 int32、uint32 或列舉。

注意事項 7

parameter-list 允許文法中較為寬鬆的 type-constructor。但編譯器僅支援結構體、資料表或聯集的版面配置。

注意事項 8

service-member 允許文法中較為寬鬆的 type-constructor。但編譯器會將此方法限制為 client_end 類型。

注意事項 9

modifier-availability讓模型擁有更多的attribute-args 但編譯器會將此引數限制為 added 和 removed 引數。